home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er 1993 June
/
64er_Magazin_93-06_1993_Markt__Technik_de_Side_B.d64
/
listing 2-3
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
926b
|
27 lines
10 rem *** puls-modulation
11 :
12 :ut=10 :rem auf-zeit (up-time)
13 :dt=10 :rem ab-zeit (down-time)
14 :ul=40 :rem auf-schritt (up-level)
15 :dl=20 :rem ab-schritt(down-level)
16 :p=400 :rem start-tastverh.(pulse)
19 :
20 rem * ton einschalten
21 :
22 s=54272:pokes+4,8:pokes+24,15 :rem volle lautstaerke
23 pokes+6,255:pokes+5,0:pokes+4,65 :rem adsr und rechteck-wellenform setzen
25 pokes,0:pokes+1,10 :rem tonhoehe setzen
26 pokes+2,pand255:pokes+3,p/256 :rem tastverhaeltnis mit lo-und hi-byte setzen
29 :
40 rem * pulse !
41 :
42 fori=0tout :rem schleife fuers hochzaehlen
43 p=p+ul :rem tastverhaeltnis um up-level erhoehen
44 pokes+2,pand255:pokes+3,p/256 :rem neues tastverhaeltnis setzen
45 next :rem schleifenende
47 fori=0todt :rem schleife fuers runterzaehlen
48 p=p-dl :rem tastverh. um down-level vermindern
49 pokes+2,pand255:pokes+3,p/256 :rem neues tastverh. setzen
50 next :rem schleifenende
52 goto42 :rem ...und nochmal...